Автор: mktwo
Перевод: Voland
Оригинал: Creating a XP system

Прежде всего убедитесь, что Вы уже знаете как устанавливать эти коды, т.к. в этом уроке это не объясняется. Во-вторых, я полагаю что Вы уже немного знакомы с UnrealScript. Например, Вы должны знать как наследуемые классы работают,и как делается свой тип игры, как сделать свой собственный HUD, PlayerController и т.д. Если Вы не знаете всего этого то можно некоторые вещи посмотреть на этом сайте, также на других русских сайтах и естественно на заморских, например тут.

HUD создан по этому уроку.


Здесь представлены файлы для работы.


MyGame.uc
MyPlayerController.uc
SeqAct_GiveXP.uc (optional)
MyHUD.uc

MyGame.uc

Скрипт содержит наш созданный тип игры

class MyGame extends UTGame;

// Функция, которая выполняется после каждого убийства
function ScoreKill(Controller Killer, Controller Other)
{
local MyPlayerController PC;

super.ScoreKill(Killer, Other);

  PC = MyPlayerController(Killer); // переход к пользовательскому классу MyPlayerController
  PC.GiveXP(100); //Позволяет изменять количество получаемого опыта
}

DefaultProperties
{
// DefaultPawnClass = class'UTGame.UTPawn'
PlayerControllerClass = class'MyGame.MyPlayerController'
HUDType = class'MyGame.MyHUD'
}



MyPlayerController.uc

Здесь мы получаем опыт, повышаем уровень. Функции не находятся в MyPawn для того чтобы опыт сохранялся после смерти.

class MyPlayerController extends UTPlayerController
config(MyGame);

const MAX_LEVEL = 50;
 const XP_INCREMENT = 500; // Количество опыта до следующего уровня
var int XP; // Общая сумма собранных XP
 var int Level; // Текущий уровень
 var int XPGatheredForNextLevel; // Количество набранного опыта 
var int XPRequiredForNextLevel; // Количество необходимых XP до нового уровня


//При старте игры мы подсчитываем сколько нужно получить опыта чтобы перейти на новый уровень

simulated function PostBeginPlay()
{
super.PostBeginPlay();

// Обсчитываем свойства при старте игры
CalculateLevelProgress();
}


//Здесь мы объявляем функцию,которая позволяет поменять кол-во опыта нужного для следующего уровня через Kismet
// Функция вызываемая из Kismet

public function AddXP(SeqAct_GiveXP action)
{
GiveXP(action.Amount); // Количество опыта получаемого с учетом установки в Kismete
}

//Функция добавления опыта
public function GiveXP(int amount)
{
self.XP += amount;

CalculateLevelProgress();

while (self.XPGatheredForNextLevel >= self.XPRequiredForNextLevel && self.Level < MAX_LEVEL)
{
self.Level++;

  // Пересчитываем опыт после "Level Up"
CalculateLevelProgress();
}
}

//Дальше мы объявляем функцию, которая считает сколько нужно еще опыта для достижения следующего уровня
private function CalculateLevelProgress()
{
local int xpToCurrentLevel; // Текущее количество накопленного опыта

xpToCurrentLevel = XP_INCREMENT * (self.Level - 1);
self.XPGatheredForNextLevel = self.XP - xpToCurrentLevel;
self.XPRequiredForNextLevel = self.Level * XP_INCREMENT;
}

DefaultProperties
{
Level = 1;
XP = 0;
 }

SeqAct_GiveXP.uc (optional)

В этом скрипте мы создаем Sequence Action, который мы будем использовать в Kismet

class SeqAct_GiveXP extends SequenceAction;

var() int Amount; // Количество XP которое это действие даст

//Добавляем немного информации, чтобы было удобнее использовать в kismet
DefaultProperties
{
// Имя функции в Kismet Editor
ObjName="Add XP"

// Имя функции при использовании
HandlerName="AddXP"

Amount = 0

  // Показывает входы и выходы блока полученного в Kismet
VariableLinks(1)=(ExpectedType=class'SeqVar_Int', LinkDesc="Amount", bWriteable=true, PropertyName=Amount)
}


Используем Kismet для изменения системы получения опыта



Сначала Вы должны сделать триггер, жмем Add Actor > Add Trigger.

Дальше выбираем триггер и идем в kismet. Добавляем триггер New Event Using Trigger_0 > Touch. Дальше добавляем Add XP-action.

Соединяем Touched с In.

Дальше New Variable > Player > Player и цепляем к target. 

New Variable > Int > Int и пишем количество начисляемого опыта за одно убийство и цепляем к Amount.

Сохраняемся и наслаждаемся результатом!